The  CLP Outfile  tool  has no  source  other than  this  documentation
member.  The  intent is that you would access  this member from the SEU
browse  function  and copy  in the  code when  you  need to  process an
outfile.

The source is in the proper format to be copied into a CL program.

The following  source  uses the  ALCTMPMBR  TAA Tool.   This  does  not
support  all outfile  types.   See  the  next section  for use  without
ALCTMPMBR.

             /* Technique for a CLP outfile with ALCTMPMBR */
             DCLF       FILE(QADSPOBJ) /* Outfile used by DSPOBJD */
             DCL        &FILE *CHAR LEN(10)
             DCL        &MBR *CHAR LEN(10)
                        /*   This basic code for reading an outfile */
                        /*    was copied from CLPOUTFILE            */
                        /*    in TAATOOL/QATTINFO.                  */
                        /* TAA Tool for allocating a member */
             ALCTMPMBR  FILETYPE(*OBJD) RTNMBR(&MBR) RTNFILE(&FILE)
             SNDSTSMSG  MSG('Outfile being created from +
                          the DSPOBJD command')
             DSPOBJD    OBJ(QGPL/*ALL) OBJTYPE(*JOBD) +
                          OUTPUT(*OUTFILE) OUTFILE(TAATOOL/&FILE) +
                          OUTMBR(&MBR *ADD)
             OVRDBF     FILE(QADSPOBJ) TOFILE(TAATOOL/&FILE) +
                          MBR(&MBR) SECURE(*YES)
             SNDSTSMSG  MSG('Processing outfile')
 READ:       RCVF       /* Read a record */
             MONMSG     MSGID(CPF0864) EXEC(GOTO EOF)
                        /*                                */
                        /*      Your processing           */
                        /*                                */
             GOTO       READ /* Loop back for next record */
 EOF:                   /* All records have been read */
             RCVMSG     MSGTYPE(*EXCP) /* Remove escape message */
             SNDSTSMSG  MSG(*REMOVE)
             /* End technique for CLP outfile with ALCTMPMBR */

Outfile code without ALCTMPMBR
------------------------------

             /* Technique for a CLP outfile without ALCTMPMBR */
             DCLF       FILE(QADSPOBJ) /* Outfile used by DSPOBJD */
             DCL        &FILE *CHAR LEN(10)
             DCL        &MBR *CHAR LEN(10)
                        /*   This basic code for reading an outfile */
                        /*    was copied from CLPOUTFILE            */
                        /*    in TAATOOL/QATTINFO.                  */
             DLTF       FILE(QTEMP/DSPOBJDP)
             MONMSG     MSGID(CPF2105) EXEC(DO) /* Does not exist */
             RCVMSG     MSGTYPE(*EXCP) /* Remove escape message */
             ENDDO      /* Does not exist */
             SNDSTSMSG  MSG('Outfile being created from +
                          the DSPOBJD command')
             DSPOBJD    OBJ(QGPL/*ALL) OBJTYPE(*JOBD) +
                          OUTPUT(*OUTFILE) OUTFILE(QTEMP/DSPOBJDP)
             OVRDBF     FILE(QADSPOBJ) TOFILE(QTEMP/DSPOBJDP) +
                          SECURE(*YES)
             SNDSTSMSG  MSG('Processing outfile')
 READ:       RCVF       /* Read a record */
             MONMSG     MSGID(CPF0864) EXEC(GOTO EOF)
                        /*                                */
                        /*      Your processing           */
                        /*                                */
             GOTO       READ /* Loop back for next record */
 EOF:                   /* All records have been read */
             RCVMSG     MSGTYPE(*EXCP) /* Remove escape message */
             SNDSTSMSG  MSG(*REMOVE)
             /* End technique for CLP outfile without ALCTMPMBR */

Command parameters
------------------

None.

Restrictions
-------------

None.

Prerequisites
-------------

None.

Implementation
--------------

None.   To allow a simple  SEU copy function, you  should use CPYTAA to
place the documentation in a source member.

Objects used by the tool
------------------------

None.